filename formltr 'c:\temp\formltr.txt';

data mailing;
infile datalines;
input @ 1 nbr     $5.0
      @ 6 lname  $10.0
      @16 fname  $10.0
      @26 addr   $15.0
      @41 city   $10.0
      @51 state   $2.0
      @53 zip     $5.0 ;
datalines;
11224Binford   Dan       469 N 400 E    DeSoto    TX75115
12111Arias     Ida       4028 Elmo Loop Merced    CA95340
32555Ryan      Richard   914 Fifth St   Normal    IL61761
41499Hilmer    Debbie    21175 Felipa   Buena ParkCA90620
55123Josephson Peggy     248 Michigan   Jamestown NY14701
61626Havlik    Cheryl    551 Washington Whittier  CA90605
77271Carpenter Lois      326 Beach      Berwyn    IL60650
81288Black     Kathy     618 S Anza     Pasadena  CA91106
81997Foote     April     635 Burns      Carol StrmIL60187
94993Dixson    Richard   1021 Brown     Chicago   IL60612
;

data _null_;
retain lm 5;  /* left margin */
set mailing;
file formltr  print notitles;
put _page_;
put ///;
x = trim(fname) || ' ' || trim(lname);
put @lm x;
put @lm addr;
x = trim(city) || ', ' || state || ' ' || zip;
put @lm x;
put ///;
x = 'Dear ' || trim(fname) || ',';
put @lm x;
put /;
put @lm 'Congratulations! You are one of a select group from ' city;
put @lm 'to be invited to visit our luxurious resort! Call 800-TIMESHR';
put @lm 'immediately for details!';
put /;
put @lm 'See you soon!';
put /;
put @lm 'Sincerely,';
put /;
put @lm 'Bill Qualls';
put @lm 'VP Promotions';
run;